Misc packages for Arch Linux
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

44 lines
1.6 KiB

  1. # Maintainer: drakkan <nicola.murino at gmail dot com>
  2. pkgname=mingw-w64-libjpeg-turbo
  3. pkgver=2.1.1
  4. pkgrel=1
  5. arch=(any)
  6. pkgdesc="JPEG image codec with accelerated baseline compression and decompression (mingw-w64)"
  7. license=("custom")
  8. depends=(mingw-w64-crt)
  9. makedepends=(yasm mingw-w64-cmake)
  10. provides=(mingw-w64-libjpeg)
  11. conflicts=(mingw-w64-libjpeg mingw-w64-libjpeg6-turbo)
  12. options=(staticlibs !strip !buildflags)
  13. url="http://libjpeg-turbo.virtualgl.org"
  14. source=("http://downloads.sourceforge.net/libjpeg-turbo/libjpeg-turbo-$pkgver.tar.gz")
  15. validpgpkeys=('0338C8D8D9FDA62CF9C421BD7EC2DBB6F4DBF434') # The libjpeg-turbo Project (Signing key for official binaries) <information@libjpeg-turbo.org>
  16. sha512sums=('9cf61b4677b38e254063248a3fdbe138634d23a35ae8f2ee2661bdb3248b1d0500bd43201b8d9fe66c779d578074fd9ed19bc097ba22e10143530c2a19738673')
  17. _architectures="i686-w64-mingw32 x86_64-w64-mingw32"
  18. build() {
  19. cd "$srcdir/libjpeg-turbo-$pkgver"
  20. for _arch in ${_architectures}; do
  21. mkdir -p build-${_arch} && pushd build-${_arch}
  22. ${_arch}-cmake -DWITH_JPEG8=ON ..
  23. make
  24. popd
  25. done
  26. }
  27. package() {
  28. for _arch in ${_architectures}; do
  29. cd "$srcdir/libjpeg-turbo-$pkgver/build-${_arch}"
  30. make DESTDIR="$pkgdir" install
  31. ${_arch}-strip --strip-unneeded "$pkgdir"/usr/${_arch}/bin/*.dll
  32. ${_arch}-strip -g "$pkgdir"/usr/${_arch}/lib/*.a
  33. if [[ $NO_EXECUTABLES ]]; then
  34. find "${pkgdir}/usr/${_arch}" -name '*.exe' -delete
  35. else
  36. find "${pkgdir}/usr/${_arch}" -name '*.exe' -exec ${_arch}-strip --strip-all {} \;
  37. fi
  38. done
  39. }
  40. # vim: ts=2 sw=2 et: